/*

 b batch file for maxima CAS



There are 2 complex planes :
* w-plane 
* z-plane 


z is a pont of z-planes
zz is a list of z points

1. draw curve on z plane 
2. draw images of z-curve  under f  on w plane               
3. draw images of z-curve under fc on w plane 




Adam Majewski
 
*/

kill(all);
remvalue(all);


/* definitions of  functions  */

f(z):= float(rectform(log(z)))$
fc(z):= float(rectform(log(z -c)))$


/* conformal map */
 g(w):=w/2-w*w/4;
 
 /* 
 circle D={w:abs(2w)=1 } where w=l(t) 
 t is angle in turns ; 1 turn = 360 degree = 2*Pi radians 
 */
 l(t):=%e^(%i*t*2*%pi);


/* converts complex number into list for draw package  */
draw_format(z):= [float(realpart(z)),float(imagpart(z))];



compile(all);



print (" ============== compute ===============  ")$
/* ---- const ----*/ 

t : (-1+sqrt(5))/2$ /* Rotation number ( internal angle) t is an irrational number = the Golden Mean  */ 
c :l(t)$
c:g(c)$


/*  c : -0.39054087 -0.58678790*%i$ */ 
 iMax:100; /* number of points to draw */
 dt:1/iMax;
 


/* curve is a list of points joned by lines */
 /* point to point method of drawing */
 t:0; /* angle in turns */ 
 /* compute first point of curve, create list and save point to this list */
 /* point of unit circle   w:l(t); */
 w:rectform(ev(l(t), numer)); 
 circleList:makelist (w, j, 1, 1); 
 while (t<=1) do
 (  t:t+dt,
    w:rectform(ev(l(t), numer)), 
    circleList:cons(w,circleList)
 );
 
 
 zz:[0, 1/4, 1/3, 1/2]$
 zz:map(l,zz)$
 zz:map(g,zz)$
 

 cardioidList: map (g, circleList)$	
 
 /* --------- map from z to w plane using   -------------------------------*/
 logList:      map (f, cardioidList)$
 logCList:     map (fc, cardioidList)$
 
 ww : map(f,zz)$
 wwc: map(fc,zz)$
 
 
/*--------------  convert lists of complex points to draw format lists --------*/

cardioidList: points(map(draw_format, cardioidList))$
 logList:     points(map(draw_format, logList))$
 logCList:    points(map(draw_format, logCList))$

 zz: points(map(draw_format, zz))$
 ww: points(map(draw_format, ww))$
 wwc: points(map(draw_format, wwc))$

/*------------------  draw ------------------------------------------------------ */

path:"~/Dokumenty/mandelbrot_planes/log/maxima/"$ /* pwd  */
FileName:"i3p"$ /* without extension which is the terminal name */





 load(draw); /* Mario Rodríguez Riotorto   http://www.telefonica.net/web2/biomates/maxima/gpdraw/index.html */
 draw(
  terminal  = 'png,
  file_name = concat(path,FileName),
  columns  = 3,
  dimensions=[1500,500], /*  x = y*columns  */
  
  gr2d(title = " z plane ",
   xlabel     = "z.re ",
   ylabel     = "z.im",
   points_joined =true,
   grid = false,
   color         = red,
   point_size    = 0.2,
   point_type = filled_circle,
   cardioidList,
   
   color=blue,
   points_joined =false,
   point_size    = 0.9,
   zz
   
  ),

  gr2d(
   title = " w plane : w =log(z)",
   xlabel     = "w.re ",
   ylabel     = "w.im",
   grid = false,
   xaxis       = false,
   points_joined =true,
   color         = red,
   point_size    = 0.2,
   point_type = filled_circle,
   logList,
   
   color=blue,
   points_joined =false,
   point_size    = 0.9,
   ww
),
gr2d(
   title = " w plane : w =log(z-c)",
   xlabel     = "w.re ",
   ylabel     = "w.im",
   /*
   yrange = [-0.5,3.5],
   xrange = [-2.5,1.5],
   */
   grid = false,
   xaxis       = false,
   points_joined =true,
   color         = red,
   point_size    = 0.2,
   point_type = filled_circle,
   logCList,
   
   color=blue,
   points_joined =false,
   point_size    = 0.9,
   wwc
   
)

 );