prologues := 2;
% input metaobj.mp;
extra_endfig := "currentpicture := currentpicture shifted -llcorner currentpicture;";
verbatimtex
%&latex
\documentclass{article}
\begin{document}
etex
beginfig(1);
  numeric u;
  u := .4cm;
  path pp;
  pp := unitsquare xscaled 30u yscaled 15u;
  label.bot(btex \tt Dry Bulb Temperature $^o$C etex,
    ((llcorner pp + lrcorner pp)/2) shifted (u * down));
  pp := llcorner pp -- 2/9[llcorner pp, ulcorner pp] {dir (15)} ..
  {dir (60)} 5/9[ulcorner pp, urcorner pp] --
  urcorner pp -- lrcorner pp -- cycle;
  draw pp;
  label.top(btex \tt Relative Humidity \% etex, (point 2.5 of pp) shifted (u * up));
  label.top (btex 100 etex, point 2 of pp);
  path hum[];
  hum8 := 4/5[point 0 of pp, point 1 of pp] {dir (15)} ..
  {dir (60)} 2/15[point 2 of pp, point 3 of pp];
  draw hum8;
  label.top(btex 80 etex, point length(hum8) of hum8);
  hum6 := 3/5[point 0 of pp, point 1 of pp] {dir (12)} ..
  {dir (55)} 6/15[point 2 of pp, point 3 of pp];
  draw hum6;
  label.top(btex 60 etex, point length(hum6) of hum6);
  hum4 := 2/5[point 0 of pp, point 1 of pp] {dir (10)} ..
  {dir (50)} 11/15[point 2 of pp, point 3 of pp];
  draw hum4;
  label.top(btex 40 etex, point length(hum4) of hum4);
  hum2 := 1/5[point 0 of pp, point 1 of pp] {dir (7)} ..
  {dir (40)} 5/15[point 3 of pp, point 4 of pp];
  draw hum2;
  label.rt(btex 20 etex, point length(hum2) of hum2);
  label.top(btex \vbox{\hbox{\tt Wet Bulb}\hbox{\tt Temperature $^o$C}} etex,
    (point 1.5 of pp) shifted (2.5u * dir (150)));
  for i=0 upto 10:
    label.bot(decimal (i * 5), (i/10)[point 0 of pp, point 4 of pp]);
  endfor;
  pair wb[];
  wb0 := point 1 of pp;
  label.top("0", wb0);
  wb1 := point 1.12 of pp;
  label.ulft("5", wb1);
  wb2 := point 1.26 of pp;
  label.ulft("10", wb2);
  wb3 := point 1.45 of pp;
  label.ulft ("15", wb3);
  wb4 := point 1.7 of pp;
  label.ulft ("20", wb4);
  wb5 := point 2 of pp;
  label.lft("25", wb5);
  for i=0 upto 5:
    draw wb[i] -- ((wb[i] + 50u * dir (-25) -- wb[i]) intersectionpoint pp);
  endfor;
  for i=1 upto 9:
    pair db;
    db := (i/10)[point 0 of pp, point 4 of pp];
    draw db -- ((db + 50u * up -- db) intersectionpoint pp);
  endfor;
  currentpicture := currentpicture scaled 1.5;
endfig;
end;